Exchange Forum > AutoLISP and Visual LISP
Printing key commands
Printing key commands

#1
mavrick1228
Join Date:
01-11-2008
 I have a guy that is not very familure w/ ACAD and I would like to help him to be more productive... I was wondering if anyone knows where I go to print out the keyboard shortcuts.. I was under customize user interface but didn't see it there.
Thanks
Printing key commands

#2
Chandler
Join Date:
09-04-2007
 Command: Aliasedit
This displays a dialog of the shortcuts in the Acad.pgp file.
However, there may be other shortcuts defined elsewhere in other loaded AutoLISP files.
Printing key commands

#3
cybermonk
Join Date:
07-28-2007
 If you're just looking for the list of the command functions the following CFunctions may help.
It doesn't show a description of the functions, only a sorted list of the function names.
 
Code: 
(defun c:CFunctions (/ CFunctions Filename Function LogFileMode)
  (setq LogFileMode (getvar "LogFileMode"))
  (setvar "LogFileMode" 0)
  (setq Filename (open (getvar "LogFilename") "w"))
  (close Filename)
  (setvar "LogFileMode" 1)
  (foreach Function (atoms-family 0)
    (princ "\n")(princ Function)
  )
  (setvar "LogFileMode" 0)
  (setq Filename (open (getvar "LogFilename") "r"))
  (while (setq Function (read-line Filename))
    (if (= (substr Function 1 2) "C:")
      (if (not (member Function CFunctions))
        (setq CFunctions (append CFunctions (list Function)))
      )
    )
  )
  (close Filename)
  (setq CFunctions (acad_strlsort CFunctions))
  (setvar "LogFileMode" 0)
  (setq Filename (open (getvar "LogFilename") "w"))
  (foreach Function CFunctions
    (write-line Function Filename)
    (princ "\n")(princ Function)
  )
  (close Filename)
  (startapp "NotePad" (getvar "LogFilename"))
  (setvar "LogFileMode" LogFileMode)
  (princ)
)
Printing key commands

#4
Buzzard
Join Date:
12-25-2007
 Look in your acad.pgp file in the acad support directory.
Printing key commands

#5
Nite Coder
Join Date:
07-28-2007
 cybermonk,
That was an interesting method using the LogFile. Here's a shorter version using the vl-symbol-name function with the atoms-family list.
 
Code: 
(defun c:Cfuns (/ Cfuns Filename OpenFile)
  (foreach Item (atoms-family 0)
    (setq Item (vl-symbol-name Item))
    (if (= (substr Item 1 2) "C:")
      (if (not (member Item Cfuns))
        (setq Cfuns (cons Item Cfuns))
      )
    )
  )
  (setq Filename (strcat (getvar "TEMPPREFIX") "Temp.txt"))
  (setq OpenFile (open Filename "w"))
  (foreach Item (acad_strlsort Cfuns)
    (write-line Item OpenFile)
    (princ "\n")(princ Item)
  )
  (close OpenFile)
  (startapp "NotePad" Filename)
  (princ)
)